2014.03.07 10:55
여기에서 자동면적,길이를 구하는 tadd란 리습을 받아 실행하려는데 실행이 안되네요....도와주세요...
;| ;;
TotalADD Total Addition v. 1.0 ;;
By: Andrea Andreetti 2009-10-20 ;;
|;
;;
(princ
"\nTotalADDition v.1.0 activated! -run \"TADD\" to start or \"TADD-r\" to end."
)
(defun c:tadd (/ itemarea itemperimeter itemlinelength
itemarclength itemsplinelength itemregionperimeter itemcircumference
itemsplineperimeter itemplineperimeter itemplinelength itemtracelength
itemarclength itemellipselength a b c d p1 p2 itemlength tarea tperim tlength
)
(vl-load-com)
(defun *oo_object_modification* (objreactor objectsmodified)
(setq selected_objects (vla-get-pickfirstselectionset
(vla-get-activedocument (vlax-get-acad-object))
)
)
(setq itemarea 0
itemperimeter 0
itemlinelength 0
itemarclength 0
itemsplinelength 0
itemregionperimeter 0
itemcircumference 0
itemsplineperimeter 0
itemplineperimeter 0
itemplinelength 0
itemtracelength 0
itemarclength 0
itemellipselength 0
)
;AREA
(vlax-for n selected_objects
(if (vlax-property-available-p n 'area)
(if (eq (vla-get-objectname n) "AcDbRegion")
(setq itemarea (+ itemarea (vla-get-area n)))
(if (vlax-curve-isclosed n)
(setq itemarea (+ itemarea (vla-get-area n)))
)
)
)
;;CIRCLE
(if (vlax-property-available-p n 'circumference)
(setq itemcircumference (+ itemcircumference (vla-get-circumference n)))
)
;;SPLINE
(if (eq (vla-get-objectname n) "AcDbSpline")
(if (vlax-curve-isclosed n)
(setq itemsplineperimeter (+ itemsplineperimeter
(vlax-curve-getdistatparam n (vlax-curve-getendparam n))
)
)
(setq itemsplinelength (+ itemsplinelength
(vlax-curve-getdistatparam n (vlax-curve-getendparam n))
)
)
)
)
;;REGION
(if (eq (vla-get-objectname n) "AcDbRegion")
(setq itemregionperimeter (+ itemregionperimeter (vla-get-perimeter n)))
)
;;PLINE
(if (or (eq (vla-get-objectname n) "AcDb2dPolyline")
(eq (vla-get-objectname n) "AcDbPolyline")
)
(if (vlax-curve-isclosed n)
(setq itemplineperimeter (+ itemplineperimeter
(vlax-curve-getdistatparam n (vlax-curve-getendparam n))
)
)
(setq itemplinelength (+ itemplinelength
(vlax-curve-getdistatparam n (vlax-curve-getendparam n))
)
)
)
)
;;LINE
(if (eq (vla-get-objectname n) "AcDbLine")
(setq itemlinelength (+ itemlinelength (vla-get-length n)))
)
;;ARC
(if (eq (vla-get-objectname n) "AcDbArc")
(setq itemarclength (+ itemarclength (vla-get-arclength n)))
)
(if (eq (vla-get-objectname n) "AcDbEllipse")
(setq itemellipselength (+ itemellipselength
(vlax-curve-getdistatparam n (vlax-curve-getendparam n))
)
)
)
;;TRACE
(if (eq (vla-get-objectname n) "AcDbTrace")
(progn (setq plist (vlax-safearray->list
(vlax-variant-value (vla-get-coordinates n))
)
)
(setq a (list (nth 0 plist) (nth 1 plist) (nth 2 plist)))
(setq b (list (nth 3 plist) (nth 4 plist) (nth 5 plist)))
(setq c (list (nth 6 plist) (nth 7 plist) (nth 8 plist)))
(setq d (list (nth 9 plist) (nth 10 plist) (nth 11 plist)))
(setq p1 (polar a (angle a b) (/ (distance a b) 2.0)))
(setq p2 (polar c (angle c d) (/ (distance c d) 2.0)))
(setq itemtracelength (+ itemtracelength (distance p1 p2)))
)
)
)
;;_end vlax-for
(setq itemperimeter (+ itemcircumference
itemsplineperimeter
itemregionperimeter
itemplineperimeter
)
)
(setq itemlength (+ itemplinelength itemsplinelength itemlinelength itemtracelength itemarclength itemellipselength)
)
(setq tarea (rtos itemarea 2 8))
(setq tperim (rtos itemperimeter 2 8))
(setq tlength (rtos itemlength 2 8))
(acet-ui-status (strcat "Toatl Area: " tarea "\n" "Total Perimeter: " tperim "\n"
"Total Length: " tlength)
)
)
;;OBJECT SELECTION
(if oo_object_modification
(progn (vlr-remove oo_object_modification)
(setq oo_object_modification nil)
)
)
(setq oo_object_modification
(vlr-miscellaneous-reactor
nil
'((:vlr-pickfirstmodified . *oo_object_modification*))
)
)
;;Command ended
(if oo_object_modification_action
(progn (vlr-remove oo_object_modification_action)
(setq oo_object_modification_action nil)
)
)
(setq oo_object_modification_action
(vlr-command-reactor nil
'((:vlr-commandended . *oo_object_modification*)
;(:vlr-commandcancelled . *oo_object_modification_CANCEL*))
)
)
)
)
(defun c:TADD-r ()
(if oo_object_modification_action
(progn (vlr-remove oo_object_modification_action)
(setq oo_object_modification_action nil)
)
)
(if oo_object_modification
(progn (vlr-remove oo_object_modification)
(setq oo_object_modification nil)
)
)
)
번호 | 제목 | 글쓴이 | 날짜 | 조회 수 |
---|---|---|---|---|
공지 | ★ 드림플러스 질문은 메일 또는 홈페이지에 부탁합니다 ★ | 아저씨 | 2017.05.16 | 2774 |
공지 | 제목이 엉망이면 답변달지 않습니다. [1] | 아저씨 | 2014.04.04 | 23854 |
공지 | 순수 캐드 질문은 고캐드로 | 아저씨 | 2013.05.28 | 68641 |
공지 | 질문 답변 게시판을 만들었습니다. | 아저씨 | 2013.02.09 | 74943 |
1669 | 드림사용중 오류 관련 문의드립니다. [1] | 사용자 | 2013.12.06 | 548 |
1668 | xref 외부참조시 도면명 일광변경때문에... [2] | 토당 | 2013.12.06 | 1327 |
1667 | 드립에 있는 리습을 사용하려는데 방법없을까요~? [1] | 뷁치수 | 2013.12.06 | 663 |
1666 | 잘쓰고 있습니다. (MDT 관련) [1] | 드림매냐 | 2013.12.07 | 590 |
1665 | Dream 설치관련 문의 [1] | 에릭 | 2013.12.08 | 505 |
1664 | 다중 플롯에 관하여.. [4] | 김DK | 2013.12.09 | 641 |
1663 | 다중플롯시... [1] | 플롯 | 2013.12.10 | 513 |
1662 | win7 64bit cad2014 사용중 오류~~ [1] | 마파람 | 2013.12.11 | 711 |
1661 | 드림에 있는 명령어 CR 문자 가운데정렬 리습문의 드립니다~~!!!! [4] | 뷁치수 | 2013.12.11 | 2526 |
1660 | 문자윈도우 질문입니다 ㅠㅠ [1] | jins | 2013.12.11 | 660 |
1659 | 익스트림 에러 [2] | 감사합니다 | 2013.12.11 | 640 |
1658 | dsp 실행오류 뜹니다. [1] | 기계기사 | 2013.12.12 | 667 |
1657 | 드림에서 더하기 빼기도 있나요? [1] | 리들러 | 2013.12.12 | 711 |
1656 | 치수 자동산정에 대한 문의 [1] | 김연수 | 2013.12.12 | 614 |
1655 | 오토캐드2014 설치시 에러관련? [1] | 우종 | 2013.12.12 | 2559 |
캐드 설치시 함께 설치하는 Express 설치되어 있어야되는 리습이네요
http://autoc.tistory.com/169 이 글 보시고 설치 안되어 있으면 설치 후 실행해보세요.
설치되었는데도 안되면
제가 아는 범위를 벗어난 것이니 고캐드 사이트의 질문방에 글 남겨보세요.